Arduino Code Editor - Speed Trap System

const int ir1Pin = 2, ir2Pin = 3, ir3Pin = 4, ir4Pin = 5;
const int ledKuningPin = 10;
const int ledMerah1Pin = A1;
const int ledMerah2Pin = A2;
const int buzzerPin = 12;

const int trig1 = 6, echo1 = 7;
const int trig2 = 8, echo2 = 9;

const float jarakCm = 14.0;
const float batasKecepatan = 1.5;
const float jarakTriggerHC = 20.0;

unsigned long waktuMulai1 = 0, waktuMulai2 = 0;
bool deteksiAwal1 = false, deteksiAwal2 = false;
bool sudahSelesai1 = false, sudahSelesai2 = false;
unsigned long lastIr1 = 0, lastIr2 = 0, lastIr3 = 0, lastIr4 = 0;
const unsigned long debounceUs = 1000;

unsigned long waktuLedKuning = 0, waktuLedMerah1 = 0, waktuLedMerah2 = 0;
bool ledKuningMenyala = false, ledMerah1Menyala = false, ledMerah2Menyala = false;

unsigned long lastUltrasonic = 0;
const unsigned long ultrasonicInterval = 100;
float jarak1 = 0, jarak2 = 0;

void setup() {
  pinMode(ir1Pin, INPUT); pinMode(ir2Pin, INPUT);
  pinMode(ir3Pin, INPUT); pinMode(ir4Pin, INPUT);
  pinMode(ledKuningPin, OUTPUT);
  pinMode(ledMerah1Pin, OUTPUT);
  pinMode(ledMerah2Pin, OUTPUT);
  pinMode(buzzerPin, OUTPUT);
  pinMode(trig1, OUTPUT); pinMode(echo1, INPUT);
  pinMode(trig2, OUTPUT); pinMode(echo2, INPUT);

int nadaBooting[] = {523, 587, 659, 587, 523};
  int durasiBooting[] = {150, 150, 200, 150, 300};
  
  for (int i = 0; i < 5; i++) {
    digitalWrite(ledKuningPin, HIGH);
    digitalWrite(ledMerah1Pin, HIGH);
    digitalWrite(ledMerah2Pin, HIGH);
    tone(buzzerPin, nadaBooting[i], durasiBooting[i]);
    delay(durasiBooting[i]);
    digitalWrite(ledKuningPin, LOW);
    digitalWrite(ledMerah1Pin, LOW);
    digitalWrite(ledMerah2Pin, LOW);
    delay(50);
  }
  
  for (int i = 0; i < 2; i++) {
    digitalWrite(ledKuningPin, HIGH);
    digitalWrite(ledMerah1Pin, HIGH);
    digitalWrite(ledMerah2Pin, HIGH);
    delay(100);
    digitalWrite(ledKuningPin, LOW);
    digitalWrite(ledMerah1Pin, LOW);
    digitalWrite(ledMerah2Pin, LOW);
    delay(100);
  }
  noTone(buzzerPin);
}

float bacaJarak(int trig, int echo) {
  digitalWrite(trig, LOW);
  delayMicroseconds(2);
  digitalWrite(trig, HIGH);
  delayMicroseconds(10);
  digitalWrite(trig, LOW);
  long duration = pulseIn(echo, HIGH, 30000);
  if (duration == 0) return 999;
  return duration * 0.034 / 2;
}

bool bacaSensorIR(int pin, unsigned long &last) {
  if (digitalRead(pin) == LOW) {
    if (micros() - last > debounceUs) {
      last = micros();
      return true;
    }
  }
  return false;
}

void prosesKecepatan(int jalur, unsigned long waktu) {
  if (waktu == 0 || waktu > 5000000) return;
  float kecepatan = (jarakCm / 100.0) / (waktu / 1000000.0) * 3.6;
  if (kecepatan > batasKecepatan) {
    int freq = constrain(map(kecepatan, batasKecepatan, batasKecepatan*3, 1500, 3500), 1500, 3500);
    tone(buzzerPin, freq, 100); delay(150);
    tone(buzzerPin, freq, 400); delay(450);
    noTone(buzzerPin);
  }
}

void loop() {
  bool ir1 = bacaSensorIR(ir1Pin, lastIr1);
  bool ir2 = bacaSensorIR(ir2Pin, lastIr2);
  bool ir3 = bacaSensorIR(ir3Pin, lastIr3);
  bool ir4 = bacaSensorIR(ir4Pin, lastIr4);
  
  if (digitalRead(ir1Pin) == LOW || digitalRead(ir4Pin) == LOW) {
    ledKuningMenyala = true;
    waktuLedKuning = millis();
    digitalWrite(ledKuningPin, HIGH);
  }
  if (ledKuningMenyala && (millis() - waktuLedKuning >= 4000)) {
    ledKuningMenyala = false;
    digitalWrite(ledKuningPin, LOW);
  }
  
  if (ir1 && !deteksiAwal1 && !sudahSelesai1) {
    deteksiAwal1 = true;
    waktuMulai1 = micros();
  }
  if (ir2 && deteksiAwal1 && !sudahSelesai1) {
    prosesKecepatan(1, micros() - waktuMulai1);
    deteksiAwal1 = false;
    sudahSelesai1 = true;
  }
  if (sudahSelesai1 && digitalRead(ir1Pin)==HIGH && digitalRead(ir2Pin)==HIGH)
    sudahSelesai1 = false;
  
  if (ir4 && !deteksiAwal2 && !sudahSelesai2) {
    deteksiAwal2 = true;
    waktuMulai2 = micros();
  }
  if (ir3 && deteksiAwal2 && !sudahSelesai2) {
    prosesKecepatan(2, micros() - waktuMulai2);
    deteksiAwal2 = false;
    sudahSelesai2 = true;
  }
  if (sudahSelesai2 && digitalRead(ir4Pin)==HIGH && digitalRead(ir3Pin)==HIGH)
    sudahSelesai2 = false;
  
  if (millis() - lastUltrasonic >= ultrasonicInterval) {
    lastUltrasonic = millis();
    jarak1 = bacaJarak(trig1, echo1);
    jarak2 = bacaJarak(trig2, echo2);
  }
  
  bool triggerMerah1 = (digitalRead(ir2Pin) == LOW) || (jarak1 <= jarakTriggerHC);
  if (triggerMerah1) {
    ledMerah1Menyala = true;
    waktuLedMerah1 = millis();
    digitalWrite(ledMerah1Pin, HIGH);
  }
  if (ledMerah1Menyala && (millis() - waktuLedMerah1 >= 4000)) {
    ledMerah1Menyala = false;
    digitalWrite(ledMerah1Pin, LOW);
  }
  
  bool triggerMerah2 = (digitalRead(ir3Pin) == LOW) || (jarak2 <= jarakTriggerHC);
  if (triggerMerah2) {
    ledMerah2Menyala = true;
    waktuLedMerah2 = millis();
    digitalWrite(ledMerah2Pin, HIGH);
  }
  if (ledMerah2Menyala && (millis() - waktuLedMerah2 >= 4000)) {
    ledMerah2Menyala = false;
    digitalWrite(ledMerah2Pin, LOW);
  }
}

total karakter: 0 untuk Arduino Uno R3 ATMEGA328P-PU

Pin Connection: